WHICH command for DOS

admin — Mon, 21 Sep 2009 11:59:34 +0000

If You need the analog of Unix ‘which’ command and do not have Resource Kit, the following batch file will help.
The code was found on www.ss64.com
Published with the permission of the author, Clay Calvert.

@echo off
SETLOCAL
(set WF=)

:: Look for file in the current directory

for %%a in ("" %%) do (
if not defined WF if exist "%~1%%~a" set WF=%CD%\%~1%%~a)

:: Look for file in the PATH

for %%a in ("" %%) do (
if not defined WF for %%g in ("%~1%%~a") do (
if exist "%%~$PATH:g" set WF=%%~$PATH:g))

:: Store the Help Error message

if NOT "%~x1"=="" goto:END
for /f "delims=." %%a in ('help.exe *') do set HlpErr=%%a

:: If command missing from Help, goto end

help.exe "%~1" |find "%HlpErr%">nul && goto:END

:: Listed in help so find file in System32

for %%a in (exe com) do (
if /i "%WF%"=="%windir%\system32\%~1.%%a" goto:END)

:: File not in System32, so must be an internal command

set WF="%~1" is an internal command

:END
if defined WF (echo.%WF%) else (
echo The file: "%~1" was not found)

:: Credits:
:: Clay Calvert
:: alt.msdos.batch.nt

Start sqlplus in Windows .BAT script

admin — Mon, 24 Aug 2009 22:37:30 +0000

Here is the example of emulating “HERE-documents” in Windows shell.

@ECHO OFF

FIND "/*%none% some_label" <%0 |sqlplus USER/PASS@SERVER

GOTO end

: ----------- embedded SQL-------------------------

/* some_label */ select count(*) from dba_free_space;
/* some_label */ select tablespace_name from dba_tablespaces;

: ----------- end of embedded SQL-------------------------

:end

It’s also possible to use procedures in .bat files.
%none% is replaced by empty string.
Spaces are mandadory in “/* some_label */” string.

MemoSoup » Windows & DOS

WHICH command for DOS

Start sqlplus in Windows .BAT script